SUMMENPRODUKT mit Spaltenzahl?

[Peter Schuerer]

Hallo Zusammen,

XL 2002.

Ich muss aus einer Datenbank ein universelles Diagramm erstellen.
Im Diagramm gibt es ein "Dropdown" für die einzelnen Positionen, die in
Tabelle1 errechnet werden sollen.
Die ausgewählte Position wird in Tabelle1 in $B$74 eingetragen.
Die Formel:
=SUMMENPRODUKT((DBProd!$T$3:$T$6000=$B76)*(DBProd!$B$3:$B$6000=C$74);(DBProd!$E$3:$E$6000))
berechnet die Werte aus E3:E6000.
In Spalte T steht der Monat als Text, Spalte B die Gruppe (1 oder 2).

Ich muss jetzt den Teil der Formel (oben) so ändern, das die Formel die
ausgewählte Position berechnet:
=SUMMENPRODUKT((DBProd!$T$3:$T$6000=$B76)*(DBProd!$B$3:$B$6000=C$74);(DBProd!Spalte$B$74$3:Spalte$B$74$6000))
Die Formel sollte eigentlich das Summenprodukt aus der Spalte bilden,
die in $B$74 als Zahl steht.
Nach 2 Stunden kriege ich es leider immer noch nicht hin, bitte dringend
um Hilfe.

MfG
Peter

[Claus Busch]

Hallo Peter,

Post by Peter Schuerer
Ich muss jetzt den Teil der Formel (oben) so ändern, das die Formel die
=SUMMENPRODUKT((DBProd!$T$3:$T$6000=$B76)*(DBProd!$B$3:$B$6000=C$74);(DBProd!Spalte$B$74$3:Spalte$B$74$6000))
Die Formel sollte eigentlich das Summenprodukt aus der Spalte bilden,
die in $B$74 als Zahl steht.

ich hoffe, dass ich dich richtig verstanden habe. Probiere es mal so:
=SUMMENPRODUKT(--(DBProd!$T$3:$T$6000=$B76);--(DBProd!$B$3:$B$6000=C$74);(INDIREKT("DBProd!"&ADRESSE(3;Tabelle1!$B$74)&":"&ADRESSE(6000;Tabelle1!$B$74))))
Die Formel wäre einfacher, wenn du für die gewünschte Spalte den
Buchstaben eintragen würdest.


Mit freundlichen Grüßen
Claus Busch

[Peter Schuerer]

Hallo Claus,

Post by Claus Busch
=SUMMENPRODUKT(--(DBProd!$T$3:$T$6000=$B76);--(DBProd!$B$3:$B$6000=C$74);(INDIREKT("DBProd!"&ADRESSE(3;Tabelle1!$B$74)&":"&ADRESSE(6000;Tabelle1!$B$74))))
Die Formel wäre einfacher, wenn du für die gewünschte Spalte den
Buchstaben eintragen würdest.

Die Formel funktioniert wunderbar.
Wie würde die einfachere Formel mit Buchstaben aussehen und wie bekomme
ich den Buchstaben in $B$74, wenn das Dropdown nur Zahlen zurück gibt.

Vielen Dank und Gruß
Peter

[Claus Busch]

Hallo Peter,

Post by Peter Schuerer
Wie würde die einfachere Formel mit Buchstaben aussehen und wie bekomme
ich den Buchstaben in $B$74, wenn das Dropdown nur Zahlen zurück gibt.

da muss auch mit INDIREKT gearbeitet werden, sie ist nur ein klein wenig
übersichtlicher.
Da du die Spalte aber mit DropDown geregelt hast, wäre der Aufwand zur
Umstellung nur deswegen zu groß.


Mit freundlichen Grüßen
Claus Busch

[Peter Schuerer]

Hallo Claus,

Post by Claus Busch
=SUMMENPRODUKT(--(DBProd!$T$3:$T$6000=$B76);--(DBProd!$B$3:$B$6000=C$74);(INDIREKT("DBProd!"&ADRESSE(3;Tabelle1!$B$74)&":"&ADRESSE(6000;Tabelle1!$B$74))))

Was bedeuten oder bewirken eigentlich die "--" in der Formel?

Gruß
Peter

[Claus Busch]

Hallo Peter,

Post by Peter Schuerer
Was bedeuten oder bewirken eigentlich die "--" in der Formel?

ich schreibe die Argumente der Formel gerne semikolongetrennt.
Dabei würden sich ohne die beiden "--" die Werte WAHR und FALSCH
ergeben. Die beiden Minuszeichen wandeln den Wahrheitswert in 1 und 0
um.
Das kannst du auch verwenden, wenn du eine Zahl aus einem String
extrahierst. Durch die Textfunktion (LINKS; RECHTS....) würde das Text
ergeben. Durch die beiden Minuszeichen wird es dann wieder zur Zahl.


Mit freundlichen Grüßen
Claus Busch

[Peter Schuerer]

Hallo Claus,

Post by Claus Busch
Durch die beiden Minuszeichen wird es dann wieder zur Zahl.

Tolle Sache, Danke.

Gruß
Peter