In Markierung leere Felder mit vorherigen Werten füllen

[Ahmed Martens]

Hallo Leute,

ich komme hier einfach nicht weiter.

Ich möchte in einer Tabelle einen bestimmten Bereich markieren und in
diesem Bereich alle leeren Tabellenfelder mit dem vorherigen Werten
füllen.

Hier mein Lösungsansatz, der nicht funktioniert:

With Range(Cells(Selection.Row, Selection.Column),
Cells(Selection.Rows.Count + Selection.Row - 1, Selection.Columns.Count
+ Selection.Column - 1))
.SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=R[-1]C"
.Value = .Value
End With

Ich bekomme immer die Fehlermeldung:

Laufzeitfehler '1004':
Anwendungs- oder objektdefinerter Fehler

und zwar immer an dieser Stelle:
=> .SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=R[-1]C"

Hat einer eine Idee was ich falsch mache?
Vielen Dank im voraus.

Gruß Ahmed

[Claus Busch]

Hallo Ahmed,

Post by Ahmed Martens
Ich möchte in einer Tabelle einen bestimmten Bereich markieren und in
diesem Bereich alle leeren Tabellenfelder mit dem vorherigen Werten
füllen.

machs doch gleich mit den Werten anstatt mit Formel und dann wandeln.
Probiers mal so:
Sub Ausfuellen()
Dim LRow As Long
Dim rngC As Range

With Selection
LRow = Cells(Rows.Count, .Column).End(xlUp).Row
For Each rngC In Range(Cells(1, .Column), Cells(LRow, .Column)) _
.SpecialCells(xlCellTypeBlanks)
rngC = rngC.Offset(-1, 0)
Next
End With
End Sub

Mit freundlichen Grüßen
Claus Busch

[Ahmed Martens]

Hallo Claus,

Post by Claus Busch
Sub Ausfuellen()
Dim LRow As Long
Dim rngC As Range
With Selection
LRow = Cells(Rows.Count, .Column).End(xlUp).Row
For Each rngC In Range(Cells(1, .Column), Cells(LRow, .Column)) _
.SpecialCells(xlCellTypeBlanks)
rngC = rngC.Offset(-1, 0)
Next
End With
End Sub

das sieht ja schon ganz gut aus, aber ich möchte ja gleich mehrere
Spalten und Zeilen bearbeiten.

Wie bekomme ich das denn hin?

Gruß Ahmed

[Claus Busch]

Hallo Ahmed,

Post by Ahmed Martens
das sieht ja schon ganz gut aus, aber ich möchte ja gleich mehrere
Spalten und Zeilen bearbeiten.

probiere mal:

Sub Ausfuellen()
Dim LRow As Long
Dim LCol As Integer
Dim rngC As Range
Dim i As Integer

With ActiveSheet
LCol = .Cells(1, .Columns.Count).End(xlToLeft).Column
For i = 1 To LCol
LRow = .Cells(Rows.Count, i).End(xlUp).Row
For Each rngC In Range(Cells(1, i), Cells(LRow, i)) _
.SpecialCells(xlCellTypeBlanks)
rngC = rngC.Offset(-1, 0)
Next
Next
End With
End Sub

Mit freundlichen Grüßen
Claus Busch

[Ahmed Martens]

Ich habe es jetzt wie folgt gelöst:
Dim rngC as Range

For Each rngC In Selection
If Len(rngC.Text) = 0 Then
rngC = rngC.Offset(-1, 0)
End If
Next

Erst der Hinweis auf rngC = rngC.Offset(-1, 0) hat mich zur Lösung
gebracht.

Also vielen Dank für den Denkanstoß.

Gruß Ahmed

[Claus Busch]

Hallo Ahmed,

Post by Ahmed Martens
Dim rngC as Range
For Each rngC In Selection
If Len(rngC.Text) = 0 Then
rngC = rngC.Offset(-1, 0)
End If
Next
Erst der Hinweis auf rngC = rngC.Offset(-1, 0) hat mich zur Lösung
gebracht.

dann musst du aber immer selektieren und musst alle Zellen durchlaufen.
Mit den SpecialCells musst du nur durch die leeren Zellen. Schau dir mal
meinen zweiten Vorschlag an, der das für alle Spalten der Tabelle
nacheinander macht.


Mit freundlichen Grüßen
Claus Busch

[Ahmed Martens]

Post by Claus Busch
dann musst du aber immer selektieren und musst alle Zellen durchlaufen.
Mit den SpecialCells musst du nur durch die leeren Zellen. Schau dir mal
meinen zweiten Vorschlag an, der das für alle Spalten der Tabelle
nacheinander macht.

Habe ich gerade ausprobiert und funktioniert einwandfrei.
Werde ich jetzt auch so nehmen.

Problem ist nur, wenn die erste Zeile keinen Wert hat, dann funktioniert
das so leider auch nicht. Die Spalte ohne führenden Wert wird dann
nämlich komplett überlaufen.

Ist in diesem Fall aber kein Problem, da es immer einen vorherigen Wert
gibt. :-)

Vielen Dank für die prompte Hilfe.

Gruß Ahmed

[Ahmed Martens]

Blödsinn was ich da gesagt habe.
Ein einfaches On Error resume next löst das Problem absolut einwandfrei.

Daher => optimale Lösung


Gruß Ahmed