Kommentar aus Zelle

[Peter Schuerer]

Hallo Zusammen,

Excel2002.

Mit diesem Makro erstelle ich Kommentare aus Zellen einer anderen Tabelle:

Sub KommentareAkt()
On Error Resume Next 'falls kein Kommentar vorhanden
ActiveSheet.Unprotect (XXXX)
Range("G1").Activate
ActiveCell.Comment.Delete
ActiveCell.AddComment
ActiveCell.Comment.Visible = False
ActiveCell.Comment.Text Text:=[Tabelle8].Range("C3") & Chr(10) & ""
End Sub

Dieses Makro möchte ich jetzt in der aktiven Tabelle, von "G1" bis "U1",
15 mal nach rechts durchlaufen lassen. Für die aktive Tabelle bekomme
ich die Schleife ja noch hin, nur wie mache ich das mit
[Tabelle8].Range("C3") ...[Tabelle8].Range("Q3")?

Danke und Gruß
Peter

[Claus Busch]

Hallo Peter,

Post by Peter Schuerer
Dieses Makro möchte ich jetzt in der aktiven Tabelle, von "G1" bis "U1",
15 mal nach rechts durchlaufen lassen. Für die aktive Tabelle bekomme
ich die Schleife ja noch hin, nur wie mache ich das mit
[Tabelle8].Range("C3") ...[Tabelle8].Range("Q3")?

probiere es mal so:

Sub KommentareAkt()
Dim i As Long
Dim myStr As String

With ActiveSheet
.Unprotect ("XXXX")

For i = 7 To 21
With .Cells(1, i)
myStr = Sheets("Tabelle8").Cells(3, i - 4) & Chr(10) & ""
If Not .Comment Is Nothing Then .Comment.Delete
.AddComment myStr
.Comment.Visible = False
.Comment.Shape.TextFrame.AutoSize = True
End With
Next
End With
End Sub


Mit freundlichen Grüßen
Claus

[Peter Schuerer]

Hallo Claus

Post by Claus Busch
myStr = Sheets("Tabelle8").Cells(3, i - 4) & Chr(10) & ""

Diese Zeile habe ich geändert:
myStr = [Tabelle8].Cells(3, i - 4) & Chr(10) & ""
Die Tabelle8 wird mit dem VBA-Namen angesprochen, falls der Excel-Name
geändert wird.

Ansonsten läuft es super. Wie immer vielen herzlichen Dank.
Wünsche noch ein schönes Wochenende.

Peter