Summe der letzten 3 Monate?

[Peter Schuerer]

Hallo Zusammen,

XL2002.

Ich steh mal wieder auf dem Schlauch.
Es soll die Summe der letzten 3 Monate ab "HEUTE" errechnet werden (ohne
den aktuellen Monat). Die Daten beginnen im Jahr 2013 und es werden fast
jeden Tag mehrere Datensätze erfasst oder auch mal nur einer pro Tag.

In Spalte A steht das Datum (formatiert als *14.03.2001).
In Spalte F stehen die Werte.
Heute ist der Monat "März" 2015 und ich benötige die Summe aus Spalte F
für Februar 2015, Januar 2015 und Dezember 2014. Es geht also über die
Jahre.
Hoffe das war verständlich und einer kann helfen.

Danke und Gruß
Peter

[Claus Busch]

Hallo Peter,

Post by Peter Schuerer
In Spalte A steht das Datum (formatiert als *14.03.2001).
In Spalte F stehen die Werte.
Heute ist der Monat "März" 2015 und ich benötige die Summe aus Spalte F
für Februar 2015, Januar 2015 und Dezember 2014. Es geht also über die
Jahre.

probiers mal so:
=SUMMENPRODUKT(--(A1:A1000>=DATUM(JAHR(HEUTE());MONAT(HEUTE())-3;1));--(A1:A1000<=MONATSENDE(DATUM(JAHR(HEUTE());MONAT(HEUTE())-3;1);2));F1:F1000)
oder so:
=SUMME(BEREICH.VERSCHIEBEN($A$1;VERGLEICH(DATUM(JAHR(HEUTE());MONAT(HEUTE())-3;1);$A$1:$A$1000;0)-1;5;MONATSENDE(DATUM(JAHR(HEUTE());MONAT(HEUTE())-3;1);2)-DATUM(JAHR(HEUTE());MONAT(HEUTE())-3;1)+1))

Oder erstelle eine Pivot-Tabelle, gruppiere nach Jahre und Monate und
filtere dann nach den letzten 3 Monaten.


Mit freundlichen Grüßen
Claus

[Peter Schuerer]

Hallo Claus,

Post by Claus Busch
=SUMMENPRODUKT(--(A1:A1000>=DATUM(JAHR(HEUTE());MONAT(HEUTE())-3;1));--(A1:A1000<=MONATSENDE(DATUM(JAHR(HEUTE());MONAT(HEUTE())-3;1);2));F1:F1000)

habe obige Formel verwendet, funktioniert (wie immer) wunderbar.

Danke und Gruß
Peter

[Alexander Wolff]

=SUMMENPRODUKT((ABS(MONAT(HEUTE())-2-MONAT(A1:A999)+12*(JAHR(HEUTE())-JAHR(A1:A999)))<2)*F1:F999)

ginge auch noch.